************************************************************************
* (C) Copyright Innoscience Corporation. All rights reserved.
* **********************************************************************
************************************************************************
************************************************************************
************************************************************************
******************************************************************                                                               *
* Models provided by Innoscience Inc. are not warranted by      *
* Innoscience Inc.
* as fully representing all of the specifications and operating *
* characteristics of the semiconductor product to which the     *
* model relates. The model describe the characteristics of a    *
* typical device.                                               *
* In all cases, the current data sheet information for a given  *
* device is the final design guideline and the only actual      *
* performance specification.                                    *
* Although models can be a useful tool in evaluating device      *
* performance, they cannot model exact device performance under *
* all conditions, nor are they intended to replace bread-       *
* boarding for final verification. Innoscience Inc. therefore   *
* does not assume any liability arising from their use.         *
* Innoscience Inc. reserves the right to change models without  *
* prior notice.                                                 *
*                                                               *
* The Simulation Model is subject to change without notice.     *
* In addition, models can be a useful tool in evaluating device *
* performance, they cannot reflect the accurate device          *
* performance under all conditions, nor are they intended to    *
* replace bread boarding for final verification.                *                      
*                                                               *                                       
*****************************************************************
* Version History:
*		 1:      Created the INN650N05 	Model       2021_12_1_15_50_21 by Yudi Yan
***
simulator lang=spectre
subckt INN650N05 (gatein drainin sourcein)
parameters  LeakI=133 Dgs1=4.3e-07 Dgs2=2.6e-13 Dgs3=0.8 Dgs4=0.23
 + Ipara=4.1880e+00 Rds=5.8120e-01 k2=2.40e+00 k3=0.35 k4=2.000e+00 k5=6.200e-01 Rds_factor=1.000e-01
 + IdsTc=4.000e-03 RdsTc=-6.800e-03 k2Tc=2.754e-03 k4Tc=1.527e-03 k5Tc=-2.320e-04 rg=4
***
 + Cgd1 = 5.0000e-13/2 Cgd2 = 8.0000e-12/2 Cgd3 = -9.0000e+00
 + Cgd4 = 8.5600e-01 Cgd5 = 5.1000e-12/2 Cgd6 = -7.7475e+00
 + Cgd7 = 1.6123e+01 Cgd8 = 1.2000e-11/5 Cgd9 = -6.0000e+01 Cgd10 = 1.0000e+01
 + Cgs1 = 8.0000e-11/2 Cgs2 = 1.8000e-11/2 Cgs3 = 1.8650e+00
 + Cgs4 = 1.2430e-01 Cgs5 = -1.7500e-11/2 Cgs6 = -1.6000e+01 Cgs7 = 3.0000e+01
 + Csd1 = 2.3000e-11/4.6 Csd2 = 1.5000e-10/4.6 Csd3 = 1.0000e+01
 + Csd4 = 1.2000e+02 Csd5 = 4.0000e-11/4.6 Csd6 = -5.5000e+01 Csd7 = 5.0000e+00
***
rd (drainin drain) resistor r=((1-Rds_factor)*Rds*(1-RdsTc*(temp-25)))
rs (sourcein source) resistor r=(Rds_factor*Rds*(1-RdsTc*(temp-25)))
rg (gatein gate) resistor r=(rg)
rcsdconv (drain source) resistor r=(1E9/LeakI)
rcgsconv (gate source) resistor r=(1E9/LeakI)
rcgdconv (gate drain) resistor r=(1E9/LeakI)
gswitch drain source bsource i=( (v(drain,source)>0) ? 
+	(Ipara*(1-IdsTc*(temp-25))*log(1.0+exp((v(gate,source)-(k2*(1-k2Tc*(temp-25))))/k3))* 
+	v(drain,source)/(1 + (k4*(1-k4Tc*(temp-25))+k5*(1-k5Tc*(temp-25))*v(gate,source))*v(drain,source)) ) :
+	(-Ipara*(1-IdsTc*(temp-25))*log(1.0+exp((v(gate,drain)-(k2*(1-k2Tc*(temp-25))))/k3))* 
+	v(source,drain)/(1 + (k4*(1-k4Tc*(temp-25))+k5*(1-k5Tc*(temp-25))*v(gate,drain))*v(source,drain)) ) )
ggsdiode gate source bsource i=( (v(gate,source)>10) ? 
+	(0.125*LeakI/1077*(Dgs1*(exp((10.0)/Dgs3)-1)+Dgs2*(exp((10.0)/Dgs4)-1))) : 
+	(0.125*LeakI/1077*(Dgs1*(exp((v(gate,source))/Dgs3)-1)+Dgs2*(exp((v(gate,source))/Dgs4)-1)))  )
ggddiode gate drain bsource i=( (v(gate,drain)>10) ? 
+	(0.125*LeakI/1077*(Dgs1*(exp((10.0)/Dgs3)-1)+Dgs2*(exp((10.0)/Dgs4)-1))) : 
+	(0.125*LeakI/1077*(Dgs1*(exp((v(gate,drain))/Dgs3)-1)+Dgs2*(exp((v(gate,drain))/Dgs4)-1))) )
C_GS  (gate source) bsource c=(Cgs1)  
G_CGS1 (gate source) bsource q=(0.5*Cgs2*Cgs4*log(1+exp((v(gate,source)-Cgs3)/Cgs4))+
+	Cgs5*Cgs7*log(1+exp((v(source,drain)-Cgs6)/Cgs7)) )
C_GD  (gate drain) bsource c=(Cgd1)  
G_CGD1 (gate drain) bsource q=(0.5*Cgs2*Cgs4*log(1+exp((v(gate,drain)-Cgs3)/Cgs4))+
+	Cgd2*Cgd4*log(1+exp((v(gate,drain)-Cgd3)/Cgd4))+
+	Cgd5*Cgd7*log(1+exp((v(gate,drain)-Cgd6)/Cgd7))+
+	Cgd8*Cgd10*log(1+exp((v(gate,drain)-Cgd9)/Cgd10)) )
C_SD  (source drain) bsource c=(Csd1) 
G_CSD1 (source drain) bsource q=(Csd2*Csd4*log(1+exp((v(source,drain)-Csd3)/Csd4))+
+	Csd5*Csd7*log(1+exp((v(source,drain)-Csd6)/Csd7)) )
***
ends INN650N05
*****************************************************************************
